Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: First and Last Names in a Page Header.

First and Last Names in a Page Header

by Allen Wyatt
(last updated February 21, 2015)

David is administering an election for a professional society and the roster of eligible voters is a worksheet. There are approximately 1,200 eligible voters, so the printout is over twenty pages long. David has a footer with the page number—which is helpful—but it would be great if he could have, in the header of each page, the first name on the page and the last name on the page.

In Excel there is no native way to do this. It is a relative snap to do in Word, however, so one solution is to paste the sorted names into a Word document and then add the desired header that shows the names. While this can work, it becomes a pain to make sure that the Word version of the list is always in sync with the Excel version of the list, and vice-versa.

If you decide you want to keep a single version of the voter list in Excel, the best way to approach the problem is to use a macro to insert the first and last names in the header. The code of such a macro, obviously, would need to be tailored to the layout of the data in your worksheet. The following macro assumes that the names are in columns A through C, with the last names (the ones you want to use for the headers) are in column C.

Sub PrintNamesInHeader()
    Dim iPages As Integer
    Dim iPage As Integer
    Dim iHorPgs As Integer
    Dim iHP As Integer
    Dim iHPNext As Integer
    Dim iCol As Integer
    Dim iColLast As Integer
    Dim lRow As Long
    Dim lRowLast As Long
    Dim sPrtArea As String

    iCol = 1        'Col A
    iColLast = 3    'Col C
    With ActiveSheet
        iPages = ExecuteExcel4Macro("Get.Document(50)")
        iHorPgs = .HPageBreaks.Count + 1
        sPrtArea = .PageSetup.PrintArea

        For iPage = 1 To iPages
            iHP = ((iPage - 1) Mod iHorPgs)
            iHPNext = iHP + 1
            If iHP = 0 Then
                If sPrtArea = "" Then
                    lRow = 1
                Else
                    lRow = .Range(sPrtArea).Cells(1).Row
                End If
            Else
                lRow = .HPageBreaks(iHP).Location.Row
            End If
            If iHPNext > .HPageBreaks.Count Then
                lRowLast = .Cells(lRow, iColLast).End(xlDown).Row
            Else
                lRowLast = .HPageBreaks(iHPNext).Location.Row - 1
            End If
            .PageSetup.LeftHeader = .Cells(lRow, iCol).Value & _
              " - " & .Cells(lRowLast, iColLast)
            .PrintOut From:=iPage, To:=iPage, preview:=True
        Next
    End With
End Sub

When you run the macro, it steps through each page of the worksheet. The headers are set for the page, then the single page is printed, and then the next page is examined and processed.

Note:

If you would like to know how to use the macros described on this page (or on any other page on the ExcelTips sites), I've prepared a special page that includes helpful information. Click here to open that special page in a new browser tab.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (9542) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: First and Last Names in a Page Header.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Invalid Names when Opening Workbook

Don't you hate opening a workbook and seeing error messages? If you see a message that some "invalid names" were detected ...

Discover More

Calculating an Age On a Given Date

Start putting dates in a worksheet (especially birthdates), and sooner or later you will need to calculate an age based ...

Discover More

Inserting a Bullet

Need to place a bullet in the middle of a sentence? There are a couple of easy ways you can do this, as described in this ...

Discover More

Excel Smarts for Beginners! Featuring the friendly and trusted For Dummies style, this popular guide shows beginners how to get up and running with Excel while also helping more experienced users get comfortable with the newest features. Check out Excel 2013 For Dummies today!

More ExcelTips (menu)

Full Path Names in Headers or Footers

Using a macro to add the full path name into a header or footer in an Excel worksheet.

Discover More

Creating Long Page Footers

Ever wish that you could create nice, long footers that appear at the bottom of each page when you print your worksheet? ...

Discover More

Putting Headers and Footers On Multiple Worksheets

You can easily create headers and footers for multiple worksheets by working with a selection set of the worksheets you ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is 8 + 7?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Excel that uses the menu interface (Excel 97, Excel 2000, Excel 2002, or Excel 2003)? This site is for you! If you use a later version of Excel, visit our ExcelTips site focusing on the ribbon interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.