Retrieving the Last Value in a Column

You may wonder if there is a way to return the last (not largest) value in a column. For instance, if there are values in A1 through A5, then you may want the value in A5 returned. Later, if values were added in A6 through A8, then the value in A8 should be returned.

There are a couple of ways that a solution can be approached. The first is to use a formula such as the following:

=INDEX(A:A,COUNT(A:A))

This formula returns the last numeric value in a column, providing that the values begin at (in this case) A1. This approach only works if all the values in the column are numeric. If the values are non-numeric, or if there are blank cells intermixed with the values, then a different approach is necessary. One way is to copy the following formula into column B, just to the right of the cells that may contain values:

=IF(ISNUMBER(A2),IF(A2<>0,ROW(A2),""),"")

In this case, the formula returns the row number of any cell in A which contains a numeric value greater than zero. The following formula can then be used to retrieve the last value in column A:

=INDEX(A:A,MAX(B:B))

This formula works because it returns the largest row number from column B, and then uses that as an index to return the corresponding value from column A.

If your range of data contains a mixture of numeric and non-numeric values (and, perhaps, even some blank cells intermixed in the range), then you might consider the following formula:

=LOOKUP(2,1/(1-ISBLANK(A:A)),A:A)

The way this formula works may not be evident at first. The ISBLANK portion returns an array that contains a True or False value for each cell in column A, depending on whether that cell is blank or not. That True or False value (which is really a 1 or 0) is subtracted from 1 so that you end up with the True values being 0 and the False values being 1.

The next step is to use the 1 or 0 values as the dividend in 1/x. This effectively "inverts" the value, and you end up with either 1 (1/1) or a #DIV/0! error (1/0). Remember that this is an array that is then used as a parameter to the LOOKUP function. What is being searched for in the array is the value 2, which does not exist there. (Remember that the array contains only the values 1 or an error value.) The LOOKUP function actually ignores all the error values in the array, and so it returns the offset, within the range A:A, of the last array element that contains a 1 value. This corresponds to the last cell in the range that is non-blank.

As you can tell, returning the last value in a column can get a bit tricky at times. A clean approach is to simply develop your own VBA function that returns the desired value. In this case you can program the function to return any value—not just numeric values. A fine example of such a function is available at John Walkenbach's Web site. Check out the following:

http://spreadsheetpage.com/index.php/tip/determining_the_last_non_empty_cell_in_a_column_or_row/

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (2512) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Retrieving the Last Value in a Column.