Switching Headers in a Frozen Row

Tim's got some worksheets that have two separate sections (let's call them upper and lower sections) that have slightly different column headers. He's frozen the top row to keep the upper section headers visible while scrolling down, but after scrolling past a certain point Tim ends up looking at lower-section data with upper-section headers still at the top. He'd like to know if there is a way to switch that frozen header row to show the lower section headers when he scrolls down to the point that only lower-section data is showing.

Yes, there is a way to do this, but it involves the use of macros. Before considering a macro-based solution, you may want to consider restructuring your data so that each of your sections are on different worksheets. (From a design perspective, this would be the easiest solution.) If this is not possible, then you need to be looking at macros.

One easy approach is to simply change what is stored in the top row (row 1) of your worksheet, depending on what row is selected. For instance, the following macro will make changes in the top row based on where the active cell is located. If it is before row 40, then one set of headers are stuffed into the first row; if after row 40 then another set of headers are stuffed.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim iBottomData As Integer

    iBottomData = 40

    If ActiveCell.Row < iBottomData Then
        Cells(1, 1).Value = "Last Name"
        Cells(1, 2).Value = "First Name"
        Cells(1, 3).Value = "Address"
        Cells(1, 4).Value = "Balance"
    Else
        Cells(1, 1).Value = "Account"
        Cells(1, 2).Value = "Sales Rep"
        Cells(1, 3).Value = "Status"
        Cells(1, 4).Value = ""
    End If
End Sub

To use the macro, just make sure that you place it in the code window for the worksheet that contains the two data sections. You should also change the value assigned to the iBottomData variable to reflect the row number of where your bottom data section starts.

If you want to actually change the frozen row as you move down the worksheet, then the macro needs to be a bit more robust. Actually, there are two macros that follow (both go, again, in the code window for the worksheet), and they are kicked into action as you change the selected cell and as you right-click on the worksheet.

Private Sub Worksheet_BeforeRightClick(ByVal _
  Target As Range, Cancel As Boolean)
    Application.ScreenUpdating = False
    ActiveWindow.FreezePanes = False
    ActiveWindow.Split = False
    Application.EnableEvents = False
    Application.Goto Cells(1, 1), scroll:=True
    With ActiveWindow
        .SplitColumn = 0
        .SplitRow = 1
    End With
    ActiveWindow.FreezePanes = True
    Application.Goto Cells(Target.Row - 1, _
      Target.Column), scroll:=True
    Application.EnableEvents = True
    On Error Resume Next        'MUST reenable events
    Application.EnableEvents = False
    ActiveCell.Offset(-1, 1 - Target.Column).Select
    ' so the right click menu doesn't popup
    ' only if this is the second header row.
    Cancel = True 
    Application.EnableEvents = True
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Application.ScreenUpdating = False
    If Cells(Target.Row, 1).Value <> "title2" Then Exit Sub
    ActiveWindow.FreezePanes = False
    ActiveWindow.Split = False
    Application.Goto Cells(Target.Row, 1), scroll:=True
    With ActiveWindow
        .SplitColumn = 0
        .SplitRow = 1
    End With
    ActiveWindow.FreezePanes = True
    On Error Resume Next        'MUST reenable events
    Application.EnableEvents = False
    ActiveCell.Offset(1, 1 - Target.Column).Select
    Application.EnableEvents = True
End Sub

The Worksheet_SelectionChange event handler automatically moves the frozen split to below the second row of headings when your active cell cursor hits that line. This line is detected in the If statement that checks if the first cell in the row contains the text "title2" or not. (Obviouly, this should be changed to reflect what will really be in that first cell.)

The Worksheet_BeforeRightClick event handler moves the frozen split back to the first set of headings but leaves the active cell at the row above the second set of headings.

You should understand that both of the macro solutions presented in this tip assume that you are actually scrolling through the worksheet and changing the selected cell as you go. (In other words, you are pressing the Down Arrow key to do your scrolling.) If you are simply changing what is displayed in the worksheet by using the vertical scroll bar, then the frozen headings won't change because you are not changing the selected cell and the event handlers never trigger.

Creating a more extensive solution would be beyond the scope of this tip because it would involve interfacing with the actual operating system. If you are interested in going this route, however, a good starting place might be this page at Chip Pearson's Web site:

http://www.cpearson.com/excel/DetectScroll.htm

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (3446) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Switching Headers in a Frozen Row.