Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Showing Filter Criteria on a Printout.

Showing Filter Criteria on a Printout

Written by Allen Wyatt (last updated June 25, 2018)
This tip applies to Excel 97, 2000, 2002, and 2003


Microsoft Excel includes some great tools that help you filter large data tables to include only the information you want displayed. In effect, the filters allow you to "slice and dice" your data until you get just what you want.

When printing out filtered data, you might want to know what slicing and dicing was done to the original data. There are several ways you can go about displaying your filtering criteria. One simple way is to use the advanced filtering capabilities of Excel, which require that you set up a small criteria table for your data. If the criteria table is made part of what you print, then you can see your filtering criteria quite easily.

If you use AutoFilter, then you need to use a different approach. One such approach is detailed at John Walkenbach's site:

http://j-walk.com/ss/excel/usertips/tip044.htm

This solution uses a user-defined function to return any filtering criteria in use in the current column. The function can be used in a cell, in that column, to display the criteria. If you are using advanced filtering, then the macro approach is a bit more complex. The following macros (there are two of them in the listing) examine what advanced criteria are in play, and then places the criteria in the left portion of the header.

Sub AddFilterCriteria()
    Dim strCriteria As String

    strCriteria = FilterCriteria()
    If strCriteria = "" Then
        strCriteria = "No Filtering Criteria"
    Else
        strCriteria = "Filter Criteria:" & Chr(10) & strCriteria
    End If

'   add Criteria string to Header/Footer
    With ActiveSheet.PageSetup
        .LeftHeader = strCriteria
    End With
End Sub

Function FilterCriteria() As String
    Dim rngCriteria As Range, col As Range, cel As Range
    Dim strCriteria As String, r As Integer, c As Integer
    Const strCriteriaRange As String = "Criteria"

    FilterCriteria = ""

    On Error Resume Next
    'Set Criteria-Range reference
    Set rngCriteria = Range(strCriteriaRange)
    If Err <> 0 Then Exit Function
    On Error GoTo 0

'   Create Criteria String
    c = 0
    For Each col In rngCriteria.Columns
        c = c + 1     ' CriteriaRange Columns
        r = 1         ' CriteriaRange Rows
        For Each cel In col.Cells
            If r = 1 Then
                strCriteria = strCriteria & "Criteria" _
                  & c & " (" & cel.Value & ") = "
            Else
                strCriteria = strCriteria & "'" & cel.Value & "'"
                If IsEmpty(cel.Offset(1, 0)) Then
                    'Add New row Char if not Last Criteria Column
                    If c < rngCriteria.Columns.Count Then
                        strCriteria = strCriteria & Chr(10)
                    End If
                    Exit For
                End If
                strCriteria = strCriteria & "  "
            End If
            r = r + 1
        Next cel    ' next criteria row
    Next col        ' next criteria column

    FilterCriteria = strCriteria
End Function

To use the macro, just run the AddFilterCriteria macro, after you have your advanced filtering set up. The macro reads the criteria table and puts together the criteria into a string that is placed in the left header.

Note:

If you would like to know how to use the macros described on this page (or on any other page on the ExcelTips sites), I've prepared a special page that includes helpful information. Click here to open that special page in a new browser tab.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (3248) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Showing Filter Criteria on a Printout.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Finding the Smallest Even Value

When processing data in a worksheet, you may have a need to know what the smallest (lowest) even value in a range is. You ...

Discover More

Expanding a Custom Dictionary

Does Word tell you that your custom dictionary is full? It might not actually be full, but even if it is you can add ...

Discover More

Error Opening Second Workbook

If you try to open a second workbook and you see an error message, it could be because of the way you are opening the ...

Discover More

Best-Selling VBA Tutorial for Beginners Take your Excel knowledge to the next level. With a little background in VBA programming, you can go well beyond basic spreadsheets and functions. Use macros to reduce errors, save time, and integrate with other Microsoft applications. Fully updated for the latest version of Office 365. Check out Microsoft 365 Excel VBA Programming For Dummies today!

More ExcelTips (menu)

Printing Multiple Worksheets on a Single Page

Got a bunch of worksheets and you want to save paper by printing multiple worksheets on a single piece of paper? There ...

Discover More

Printing Limited Pages from a Range of Worksheets

Need to print just a few pages from a group of worksheets? The easiest way to handle the task may be through a macro, as ...

Discover More

Printing Only Non-Blank Worksheets

If you have a workbook containing many worksheets, you might want to print only those worksheets that have some sort of ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] (all 7 characters, in the sequence shown) in your comment text. You’ll be prompted to upload your image when you submit the comment. Maximum image size is 6Mpixels. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is 6 - 3?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Excel that uses the menu interface (Excel 97, Excel 2000, Excel 2002, or Excel 2003)? This site is for you! If you use a later version of Excel, visit our ExcelTips site focusing on the ribbon interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.