Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Printing All or Nothing.

Printing All or Nothing

by Allen Wyatt
(last updated December 17, 2014)

Karen is looking for a way to print an entire workbook, even if a user chooses to print a single worksheet. In other words, she is looking for a way to print either the entire workbook, or nothing at all—there should be no "in between" options.

The only way to handle this is through the use of a macro. VBA allows you to create macros that are initiated when certain events occur. One of the events that can trigger macros is the "print" event. When someone asks to print, or chooses to see a print preview, the BeforePrint event of the Workbook object is triggered. You can create your own macro that executes when the event is triggered.

Private Sub Workbook_BeforePrint(Cancel As Boolean)
    Dim sht As Variant
    Dim bPreview As Boolean
    Dim iResponse As Integer
    On Error GoTo ErrHandler

    iResponse = MsgBox(prompt:="Do you want to Print Preview?", _
        Buttons:=vbYesNoCancel, Title:="Preview?")

    Select Case iResponse
        Case vbYes
            bPreview = True
        Case vbNo
            bPreview = False
        Case Else
            GoTo ExitHandler
    End Select
    Application.EnableEvents = False
    For Each sht In Sheets
        If sht.Visible Then
            sht.PrintOut Preview:=bPreview
        End If
    Next

ExitHandler:
    Application.EnableEvents = True
    Cancel = True
    Exit Sub

ErrHandler:
    MsgBox Err.Description
    Resume ExitHandler
End Sub

Whenever Excel gets ready to print, or whenever print preview is invoked, the BeforePrint event is triggered and this macro runs. The macro first asks the user if he or she wants to do a print preview. A Select Case structure is used to set the bPreview variable based on the answer to the question. The setting of bPreview then controls what happens.

If the user clicked Cancel when asked about previewing, then the macro is exited and the printing is canceled. Otherwise, each worksheet in the workbook is examined to either print or preview. If the worksheet is visible, it is printed, and the Preview property is set equal to bPreview (True means that the worksheet is previewed; False means it is actually printed).

Notice that the macro sets the EnableEvents property to False. This is done so that no other events can trigger while printing or previewing. If EnableEvents is left "on," then every time the PrintOut method is used, the entire BeforePrint event is again triggered—the user would end up in an endless loop if event handling were not turned off.

Also, note that one of the last things to occur before exiting the macro is that the Cancel property is set to True. This is done so that the original print or print preview request that generated the BeforePrint event is cancelled. There is, after all, no need to complete that request, and the macro did all the print handling for the user.

There is one caveat, of course, to using this approach to printing: If macros are not enabled, the handler will not run and the user can print as desired. (Holding Shift while opening the workbook disables macros and the user most times is asked if they want to enable macros.) Other issues of ExcelTips have discussed this fact.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (3329) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Printing All or Nothing.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Keeping Full Menus Displayed

Word allows menus to be displayed in two modes. The default mode, which displays menu options dynamically, drives some people ...

Discover More

Understanding the No-Width Characters

Search through the Symbol dialog box, and you may see some special characters whose names seem odd. These are the no-width ...

Discover More

Finding Text Boxes

Need to search for various text boxes in your document? It's easy to do with the handy macro provided in this tip.

Discover More

Solve Real Business Problems Master business modeling and analysis techniques with Excel and transform data into bottom-line results. This hands-on, scenario-focused guide shows you how to use the latest Excel tools to integrate data from multiple tables. Check out Microsoft Excel 2013 Data Analysis and Business Modeling today!

More ExcelTips (menu)

Printing Odd or Even Pages

When you print a worksheet, Excel normally prints all the pages or a consecutive series of pages that you specify. If you wan ...

Discover More

Printing a Number of Different Pages

If you don't need to print an entire workbook, it can be confusing to figure out how to print just certain pages. This tip ...

Discover More

Adjusting Comment Printouts

Need to print out comments, but in a way that you control what is included in the printout? Here's a way you can extract the ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments

If you would like to add an image to your comment (not an avatar, but an image to help in making the point of your comment), include the characters [{fig}] in your comment text. You’ll be prompted to upload your image when you submit the comment. Images larger than 600px wide or 1000px tall will be reduced. Up to three images may be included in a comment. All images are subject to review. Commenting privileges may be curtailed if inappropriate images are posted.

What is two minus 2?

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)


This Site

Got a version of Excel that uses the menu interface (Excel 97, Excel 2000, Excel 2002, or Excel 2003)? This site is for you! If you use a later version of Excel, visit our ExcelTips site focusing on the ribbon interface.

Newest Tips
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.