Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Maintaining the Active Cell.

Maintaining the Active Cell

by Allen Wyatt
(last updated July 23, 2011)

An Excel workbook can contain any number of individual worksheets. As you move around within the various worksheets, Excel keeps track of which cell is selected in which worksheet. When you switch to a new worksheet, Excel makes active the cell that was last active within that worksheet. Thus, if you last selected cell F9 in the worksheet, that is the one that is selected when you display the worksheet again, regardless of what was selected in the previous worksheet.

For some workbooks, however, you may want Excel to make the active cell in the selected worksheet the same as the active cell in the previous worksheet. There is no setting to automatically do this in Excel, but there are a couple of things you can try. One thing is to follow these steps:

  1. Hold down the Ctrl key as you click on the tab of the worksheet you want to go to. Two worksheet tabs should now be selected; the one with the bold name is the one that is actually displayed on the screen.
  2. Click on the tab for the worksheet you want to go to. Both tabs should still be selected, but just the one you clicked on should have its name in bold.
  3. Hold down the Ctrl key as you click on the tab of the worksheet you just left.

These steps work because you are "grouping" worksheets. When you do, Excel makes the selected cells the same for all worksheets in the group.

Remembering to use the Ctrl-click-click-Ctrl sequence can be cumbersome, at best. It is also a sequence that can be fraught with danger, because if you forget to do step 3, you could end up making unintended changes on your worksheets. (While you are working with grouped worksheets, any change you make on one sheet is similarly changed on all the sheets in the group.)

These three steps cannot be automated with macros, but you can take a different approach with a macro to accomplish the same task. The first thing you need to do is declare a public variable anywhere within a module of the workbook, as shown here:

Public sAddress As String

This variable, sAddress, will be used to store the current address of the active cell. In the "ThisWorkbook" module of the workbook, add these two macros:

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, _
  ByVal Target As Excel.Range)
    sAddress = ActiveCell.Address
End Sub
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    On Error Resume Next
    If sAddress > "" Then Sh.Range(sAddress).Select
End Sub

The first macro is run automatically by Excel any time that the selected cell changes. All it does is retrieve the address of whatever cell is active, and then store that address in the sAddress variable.

The second macro is automatically run whenever a workbook is activated. It checks to see if there is anything stored in sAddress. If there is, it selects whatever cell address is stored there. The error code is necessary in case you select a sheet that doesn't use cells, such as a chart sheet.

This macro approach works great if you only want to make this navigational change in a single workbook or two. If you prefer to make the change "system wide" (so to speak), you must be a little more complex in your approach to the macro. In this case, you need to place your code in the Personal.xls workbook so that it is loaded every time you start Excel. Specifically, place the following code into a new class module of the Personal.xls workbook. This class module should be named something descriptive, such as ClassXLApp:

Public WithEvents gobjXLApp As Excel.Application
Private mstrAddress As String

Private Sub gobjXLApp_WorkbookActivate(ByVal Wb As Excel.Workbook)
    On Error Resume Next
    If mstrAddress > "" Then ActiveSheet.Range(mstrAddress).Select
End Sub

Private Sub gobjXLApp_SheetActivate(ByVal Sh As Object)
    On Error Resume Next
    If mstrAddress > "" Then Sh.Range(mstrAddress).Select
End Sub

Private Sub gobjXLApp_SheetSelectionChange(ByVal Sh As Object, _
  ByVal Target As Excel.Range)
    mstrAddress = Selection.Address
End Sub

Next, open the "ThisWorkbook" module of Personal.xls and copy the following code to it:

Private mobjXLApp As New ClassXLApp

Private Sub Workbook_Open()
    Set mobjXLApp.gobjXLApp = Excel.Application
End Sub

Once you save Personal.xls and restart Excel, the range in the first workbook that opens will be selected in the next worksheet that is selected.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (3205) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Maintaining the Active Cell.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Large Numbers in the MOD Function

There is a known bug in the MOD function that stops it from working with large numbers and small divisors. This tip examines ...

Discover More

Drop-Down List Font Sizes

Excel has several features that cannot be customized. The font size in the drop-down lists is one of them. If you need make ...

Discover More

The Last Business Day

Many businesses need to know when the last business day of the month occurs. This tip discusses several ways you can ...

Discover More

Excel Smarts for Beginners! Featuring the friendly and trusted For Dummies style, this popular guide shows beginners how to get up and running with Excel while also helping more experienced users get comfortable with the newest features. Check out Excel 2013 For Dummies today!

MORE EXCELTIPS (MENU)

Viewing Your Work Full-Screen

Want to use the maximum space possible for displaying information on screen? You'll want to learn how to use the full-screen ...

Discover More

Task Pane Doesn't Appear Properly

Excel 2002 and 2003 include a Task pane that provides quick access to common tasks. The Task pane is normally visible when ...

Discover More

Forcing Stubborn Recalculation

Have you ever recalculated a worksheet, only to notice that not everything calculated as it should? Here's a way you can ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments for this tip:

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)

This Site

Got a version of Excel that uses the menu interface (Excel 97, Excel 2000, Excel 2002, or Excel 2003)? This site is for you! If you use a later version of Excel, visit our ExcelTips site focusing on the ribbon interface.

Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.

Links and Sharing
Share