Finding Cells Filled with a Particular Color

Vanita asked if there is a way to select cells containing a specific color. Accomplishing the task is easy if you are using Excel 2003. Just follow these steps:

1. Press Ctrl+F to display the Find tab of the Find and Replace dialog box. (See Figure 1.)



Figure 1. The Find tab of the Find and Replace dialog box.

2. Make sure there is nothing in the Find What box.
3. Click Format. (You may need to click Options to see the Format button.) Excel displays the Find Format dialog box.
4. Make sure the Patterns tab is displayed. (See Figure 2.)



Figure 2. The Patterns tab of the Find Format dialog box.

5. From the colors available, choose the color you want to find.
6. Click OK to close the Find Format dialog box.
7. Click Find All. The Find and Replace dialog box expands to show the addresses of all the cells formatted with the color you specified in step 5. (See Figure 3.)



Figure 3. The expanded Find and Replace dialog box.

8. Click one of the cell addresses in the bottom of the dialog box. Excel selects the cell within the actual worksheet.
9. Press Ctrl+A. All of the addresses within the dialog box are selected.
10. Click Close. All the cells of the desired color are selected.

If you are using Excel 97, Excel 2000, or Excel 2002 the only way to select cells of a particular color is to use a macro. Consider the macro shown here:

Sub SelectColoredCells()
    Dim rCell As Range
    Dim lColor As Long
    Dim rColored As Range

    'Select the color by name (8 possible)
    'vbBlack, vbBlue, vbGreen, vbCyan,
    'vbRed, vbMagenta, vbYellow, vbWhite
    lColor = vbBlue

    'If you prefer, you can use the RGB function
    'to specify a color
    'lColor = RGB(0, 0, 255)

    Set rColored = Nothing
    For Each rCell In Selection
        If rCell.Interior.Color = lColor Then
            If rColored Is Nothing Then
                Set rColored = rCell
            Else
                Set rColored = Union(rColored, rCell)
            End If
        End If
    Next
    If rColored Is Nothing Then
        MsgBox "No cells match the color"
    Else
        rColored.Select
        MsgBox "Selected cells match the color:" & _
            vbCrLf & rColored.Address
    End If
    Set rCell = Nothing
    Set rColored = Nothing
End Sub

To use the macro, select a range of cells before running it. The macro then steps through each selected cell and compares its color with whatever color you specify in lColor. If a match is found, then the cell is added to a selection set. When completed, the macro selects only those matching cells, and then exits.

If you would like to find out other macro-based solutions, you can refer to the following article at the Microsoft Knowledge Base:

http://support.microsoft.com/kb/142122

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (2396) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Finding Cells Filled with a Particular Color.