Loading
Excel.Tips.Net ExcelTips (Menu Interface)

Aborting a Macro and Retaining Control

Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Aborting a Macro and Retaining Control.

When you are developing a macro for others to use, you may want to add a method for the user to exit your macro before it ends, and still retain control of what the macro does. Ctrl+Break will stop a macro, but it doesn't exit gracefully, as it allows the user to view the code in the VBA Editor.

There are several ways you can approach this problem. The first is to build a "do you want to exit" prompt into your macro, and then have the macro display the prompt periodically. For instance, consider the following code:

Do ...

    '    your code goes here

    Counter = Counter + 1
    If Counter Mod 25 = 0 Then
        If MsgBox("Stop Macro?", vbYesNo) = vbYes Then End
    End If
Loop

The macro construction is based on the premise that you have a series of steps you want to repeat over and over again, through the use of a Do ... Loop structure. Every time through the loop, the value of Counter is incremented. Every 25 times through the loop, the "stop macro?" prompt is displayed, and the user has a chance to exit.

This approach is easy to implement and may work quite well for some purposes. The biggest drawback to this approach, however, is that it doesn't allow immediacy—the user must wait to exit the macro until at least 25 iterations have occurred.

Another approach is to "hide" the VBA code and apply a password to it. You do this by following these steps from within the VBA Editor:

  1. Choose the VBAProject Properties option from the Tools menu. The editor displays the Project Properties dialog.
  2. Make sure the Protection tab is displayed. (See Figure 1.)
  3. Figure 1. The Protection tab of the Project Properties dialog box.

  4. Choose the Lock Project for Viewing check box.
  5. In the Password box, enter a password you want used to protect the macro.
  6. In the Confirm Password box, enter the same password a second time.
  7. Click OK.

Close the VBA Editor, then save the workbook. With the VBA project protected, the user can still click Ctrl+Break to stop the macro, but they won't be able to get to the actual program code. They will only be able to choose from the Continue or End buttons, both of which protect your code. As an added benefit, this approach also restricts the user from viewing your code by using menu, toolbar, or ribbon choices.

Perhaps the best approach, however, is to create an error handler that will essentially take charge whenever the user presses Esc or Ctrl+Break. The handler that is run can then ask the user if they really want to quit, and then shut down gracefully if they do. Here's some example code that shows how this is done:

Sub Looptest()
    Application.EnableCancelKey = xlErrorHandler
    On Error GoTo ErrHandler

    Dim x As Long
    Dim y As Long
    Dim lContinue As Long

    y = 100000000
    For x = 1 To y Step 1
    Next

    Application.EnableCancelKey = xlInterrupt
    Exit Sub

ErrHandler:
    If Err.Number = 18 Then
        lContinue = MsgBox(prompt:=Format(x / y, "0.0%") & _
          " complete" & vbCrLf & _
          "Do you want to Continue (YES)?" & vbCrLf & _
          "Do you want to QUIT? [Click NO]", _
          Buttons:=vbYesNo)
        If lContinue = vbYes Then
            Resume
        Else
            Application.EnableCancelKey = xlInterrupt
            MsgBox ("Program ended at your request")
            Exit Sub
        End If
    End If

    Application.EnableCancelKey = xlInterrupt
End Sub

Notice that this example uses the EnableCancelKey method, assigning it the name of the label that should be jumped to if the cancel key (Esc or Ctrl+Break) is pressed. In this case, ErrHandler is jumped to, and the user is asked what to do. If the user chooses to exit, then the macro is shut down gracefully.

Notice that the first thing done after the ErrHandler label is to check if the Number property of the Err object is equal to 18. If it is, you know that a cancel key was pressed. If not, then some other type of error occurred, and it should be handled in whatever way is appropriate for your macro.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (3021) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Aborting a Macro and Retaining Control.

Related Tips:

Professional Development Guidance! Four world-class developers offer start-to-finish guidance for building powerful, robust, and secure applications with Excel. The authors show how to consistently make the right design decisions and make the most of Excel's powerful features. Check out Professional Excel Development today!

 

Leave your own comment:

*Name:
Email:
  Notify me about new comments ONLY FOR THIS TIP
Notify me about new comments ANYWHERE ON THIS SITE
Hide my email address
*Text:
*What is 5+3 (To prevent automated submissions and spam.)
 
 
           Commenting Terms

Comments for this tip:

Barry    18 Sep 2016, 05:55
@Joe,

See my comments dated 28th May 2016.
Joe    17 Sep 2016, 08:03
This does NOT work with Excel 2016. Neither the ESC Key nor the Ctrol-Break key will interrupt the loop and trigger an error.

I pasted the code as is and started the LoopTest sub from a macro button on one of my sheets in the workbook!
Barry    28 May 2016, 05:28
IMHO, using Ctrl+Break will never cause a "clean" break in program execution, except for the simplest of macros. It is likely that here are several lines of code in the main loop of the macro, and there is a high probability that the Ctrl+Break will be actioned during the execution of this code. Therefore the some lines will have been executed and others will not have been executed in the pass through this code when the Ctrl+Break occurs, this will leave the data in an unknown state.

A better way would be to have button control on the visible worksheet or a modeless Userform which when clicked would set a flag which the main macro tests at the end of each pass through the loop, together with a DoEvents instruction to allow the user the opportunity to click the "Stop" button. I would also recommend disabling the Ctrl+Break function during the execution of the code (and re-enabling at the end of course) to prevent interruption in this way. These extra lines of code will slow the macro down a bit but are worthwhile to ensure things don't get messed up.
 
 

Our Company

Sharon Parq Associates, Inc.

About Tips.Net

Contact Us

 

Advertise with Us

Our Privacy Policy

Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

DriveTips (Google Drive)

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2016)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2016)

Our Products

Helpful E-books

Newsletter Archives

 

Excel Products

Word Products

Our Authors

Author Index

Write for Tips.Net

Copyright © 2016 Sharon Parq Associates, Inc.