Loading
Excel.Tips.Net ExcelTips (Menu Interface)

Setting Program Window Size in a Macro

Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Setting Program Window Size in a Macro.

Christopher needs, within a macro, to set the size of the Excel program window. He knows how to set the size of a worksheet within the program window, but that isn't what he needs. He wonders how he can set the overall size of the program window, plus make sure that he doesn't set it larger than the user's actual screen size.

This can be done rather easily if one knows which objects and properties to use in your macro. The object you want to use is the Application object, which refers to the Excel application. Here are the pertinent properties:

  • Top. The screen pixel at which the top edge of the application window should be placed.
  • Left. The screen pixel at which the left edge of the application window should be placed.
  • Width. The width of the application window, in pixels.
  • Height. The height of the application window, in pixels.

With these in mind, you could set the position and size of the program window in this manner:

Sub SetWindowSize1()
    Application.WindowState = xlNormal
    Application.Top = 25
    Application.Left = 25
    Application.Width = 300
    Application.Height = 200
End Sub

This macro specifies the upper-left corner of the program window to be 25 pixels from the top of the screen and 25 pixels from the left of the screen. Then, the program window is set to be 300 pixels wide and 200 pixels tall. Note, as well, the setting of the WindowState property at the first of the macro. This sets the window to be in a "normal" state, meaning one that can be resized to something larger than minimized and smaller than maximized. (If you want the Excel program window to take their entire screen, simply set the WindowState property to xlMaximized and forget the rest of the settings in the macro.)

Of course, this macro sets the Excel program window to be rather small. In all likelihood you'll want it to be larger, but you don't want it to be larger than the size of the user's screen. The easiest way to figure out the size of the user's screen is to simply maximize the Excel application window and then look at the Width and Height properties. You can then adjust those figures based on where you want the upper-left corner of the screen to be and then adjust accordingly.

As an example, let's say that you want the program window to start at 25, 50 and you want it to be 1000 x 500. You could use code similar to the following:

Sub SetWindowSize2()
    Dim iMaxWidth As Integer
    Dim iMaxHeight As Integer
    Dim iStartX As Integer
    Dim iStartY As Integer
    Dim iDesiredWidth As Integer
    Dim iDesiredHeight As Integer

    iStartX = 50      ' Distance from left
    iStartY = 25      ' Distance from top
    iDesiredWidth = 1000
    iDesiredHeight = 500

    With Application
        .WindowState = xlMaximized
        iMaxWidth = Application.Width
        iMaxHeight = Application.Height

        ' Adjust for starting point
        iMaxWidth = iMaxWidth - iStartX
        iMaxHeight = iMaxHeight - iStartY
        If iDesiredWidth > iMaxWidth Then
            iDesiredWidth = iMaxWidth
        End If
        If iDesiredHeight > iMaxHeight Then
            iDesiredHeight = iMaxHeight
        End If

        .WindowState = xlNormal
        .Top = iStartY
        .Left = iStartX
        .Width = iDesiredWidth
        .Height = iDesiredHeight
    End With
End Sub

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (10938) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Setting Program Window Size in a Macro.

Related Tips:

Professional Development Guidance! Four world-class developers offer start-to-finish guidance for building powerful, robust, and secure applications with Excel. The authors show how to consistently make the right design decisions and make the most of Excel's powerful features. Check out Professional Excel Development today!

 

Comments for this tip:

Roger    19 Oct 2013, 08:31
This sets the "external" size of the application. How do I set the "internal" size?

Leave your own comment:

*Name:
Email:
  Notify me about new comments ONLY FOR THIS TIP
Notify me about new comments ANYWHERE ON THIS SITE
Hide my email address
*Text:
*What is 3+4? (To prevent automated submissions and spam.)
 
          Commenting Terms
 
 

Our Company

Sharon Parq Associates, Inc.

About Tips.Net

Contact Us

 

Advertise with Us

Our Privacy Policy

Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

DriveTips (Google Drive)

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2013)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2013)

Our Products

Premium Newsletters

Helpful E-books

Newsletter Archives

 

Excel Products

Word Products

Our Authors

Author Index

Write for Tips.Net

Copyright © 2014 Sharon Parq Associates, Inc.