Determining Business Quarters from Dates

Robert is looking for a way to determine the business quarter in which a particular date falls. For example, if cell A1 has 2/15/08, he would want cell B1 to contain a formula that returned Q1-08. Similarly, if cell A1 has 8/1/07, he would want cell B1 to return Q3-07.

There are literally dozens of ways that you can determine a straight business quarter from a date. A few of these methods are worth examining, and they are easily modified to adapt to any specific needs. What is assumed here is that you really want to use a self-contained formula, rather than using a lookup table or a VBA macro. Both of those approaches will work just fine, but it is assumed that the simple formulas will work best for your purposes.

The key factor in determining the business quarter is to look at the month of the date. One way to do that examination is to use a formula that relies on the CHOOSE function. Consider the following:

=CHOOSE(MONTH(A1),"Q1","Q1","Q1","Q2","Q2",
"Q2","Q3","Q3","Q3","Q4","Q4","Q4") & "-"
& RIGHT(YEAR(A1),2)

This is a single formula; it is rather long, providing a choice for each of the 12 months in the year. Each month returns the quarter portion of the result, and then the text for the year is appended.

Another way is to rely on IF statements to determine the quarter. This is done in the following manner:

=IF(MONTH(A1)<=3,"Q1",IF(MONTH(A1)<=6,"Q2",
IF(MONTH(A1)<=9,"Q3","Q4")))&"-"&TEXT(A1,"yy")

The IF statements check the month to see its relation to the various boundaries for the quarters (3, 6, and 9) and then assigns a proper quarter (Q1, Q2, Q3, or Q4) based on the result. A dash and the last two digits of the year is then appended to the quarter.

You can make the formula even shorter by calculating the quarter directly based upon the month. For instance, the following will take the month and return a value of 1 to 4 based on the month:

=INT((MONTH(A1)-1)/3)+1

This formula can be incorporated into a larger formula in this way:

="Q" & INT((MONTH(A1)-1)/3)+1 & "-" & RIGHT(YEAR(A1),2)

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (3339) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Determining Business Quarters from Dates.