Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Alphabetizing Worksheet Tabs.

Sorting Worksheets

by Allen Wyatt
(last updated November 29, 2014)

If you are working on a project that uses a lot of worksheets in a workbook, you may want to sort them by worksheet name. The following short macro will do the trick very nicely:

Sub SortSheets()
    Dim I As Integer, J As Integer

    For I = 1 To Sheets.Count - 1
        For J = I + 1 To Sheets.Count
            If UCase(Sheets(I).Name) > UCase(Sheets(J).Name) Then
                Sheets(J).Move Before:=Sheets(I)
            End If
        Next J
    Next I
End Sub

This macro works if you have a relatively low number of worksheets in your workbook. If, when you run the macro, you note that it takes a great deal of time to run, you may want to use a more efficient sorting algorithm in the macro. For instance, the following is a version that reads the names of all the worksheets into an array, sorts the array using the BubbleSort algorithm, and then does the actual arranging:

Sub SortSheets()
    Dim I As Integer
    Dim sMySheets() As String
    Dim iNumSheets As Integer

    iNumSheets = Sheets.Count
    Redim sMySheets(1 To iNumSheets)

    For I = 1 To iNumSheets
        sMySheets(I) = Sheets(I).Name
    Next I

    BubbleSort sMySheets

    For I = 1 To iNumSheets
        Sheets(sMySheets(I)).Move Before:=Sheets(I)
    Next I
End Sub
Sub BubbleSort(sToSort() As String)
    Dim Lower As Integer, Upper As Integer
    Dim I As Integer, J As Integer, K As Integer
    Dim Temp As String

    Lower = LBound(sToSort)
    Upper = UBound(sToSort)
    For I = Lower To Upper - 1
        K = I
        For J = I + 1 To Upper
            If sToSort(K) > sToSort(J) Then
                K = J
            End If
        Next J
        If I <> K Then
            Temp = sToSort(I)
            sToSort(I) = sToSort(K)
            sToSort(K) = Temp
        End If
    Next I
End Sub

Anyone who has programmed for some time knows that BubbleSort is a good general-purpose sorting routine, but there are faster ones available. For instance, if you have quite a few worksheets, and they start out very disorganized, you may find that the QuickSort algorithm is more beneficial. All you would need to do to change the above to use QuickSort is add the QuickSort algorithm as a subroutine (you can find the algorithm in any good Visual Basic programming book) and then call the procedure from within the main SortSheets macro. (This means changing the line where BubbleSort is now called.)

There is another difference between this second macro and the first. The first macro does not pay attention to the case of the text used to name your worksheets. Thus, My Worksheet would be viewed the same as MY WORKsheet. The second macro does pay attention to text case, and sorts accordingly. Of course, this is not a particularly big issue, since Excel doesn't pay attention to case in worksheet names, either.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (1959) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Alphabetizing Worksheet Tabs.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Inserting the User's Name in a Cell

Need to understand who is using a particular workbook? There are a number of ways you can find out, as discussed in this tip.

Discover More

Changing Outline Structure

When working with the outline of a document, you can easily move whole sections of your document. It is as easy as selecting ...

Discover More

Too Many Cell Formats

The error message "too many cell formats" can be difficult to fix. This tip describes ways you can attempt to get rid of the ...

Discover More

Excel Smarts for Beginners! Featuring the friendly and trusted For Dummies style, this popular guide shows beginners how to get up and running with Excel while also helping more experienced users get comfortable with the newest features. Check out Excel 2013 For Dummies today!

MORE EXCELTIPS (MENU)

Automatically Sorting as You Enter Information

When entering information into a worksheet, you may want it to always be in a correctly sorted order. Excel allows you to ...

Discover More

Sorting for a Walking Tour

Want to sort addresses by even and odd numbers? By using a formula and doing a little sorting, Excel can return the addresses ...

Discover More

Sorting Letters and Numbers

Sorting information in a worksheet can be confusing when Excel applies sorting rules of which you are unaware. This is ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments for this tip:

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)

This Site

Got a version of Excel that uses the menu interface (Excel 97, Excel 2000, Excel 2002, or Excel 2003)? This site is for you! If you use a later version of Excel, visit our ExcelTips site focusing on the ribbon interface.

Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.

Links and Sharing
Share