# Calculating the Last Day in a Week Number

Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Calculating the Last Day in a Week Number.

You probably know that you can use the WEEKNUM function to return the week number in a year for a given date. What if you want to do the reverse—to determine the last day of a particular week if all you have is the week number within the year? For instance, if you were to specify week 37, you would like to figure out the date of the last day in that particular week.

There is no built-in function to figure out the desired date, but there are a number of ways that you can approach the problem and figure it out. In these examples we will assume that the year is in cell A1 and the desired week number is in cell B1.

The first approach is to calculate the first day of the desired year, add seven days for each of the weeks, and then subtract the weekday number for the first day of the year.

```=DATE(A1,1,1)+B1*7-WEEKDAY(DATE(A1,1,1))
```

This formula returns a date that always represents the last day of the week, if the week ends on a Saturday. If you want the week to end on a different day of the week then the formula becomes more complex. If you want the week to end on a Sunday, then you simply need to add 1 to the formula:

```=DATE(A1,1,1)+B1*7-WEEKDAY(DATE(A1,1,1))+1
```

Applying this same logic, you might think that you could figure out weeks ending on Friday by simply subtracting 1 from the formula. This is not the case since you are using the beginning of the year as your base. If you subtract 1, you run into the problem where January 1 of whatever year is a Saturday; if you subtract 1 you don't end up with the first Friday of the year but instead end up with December 31 of the previous year. To calculate for weeks ending on Friday you need a much more complex formula:

```=DATE(A1,1,6-WEEKDAY(DATE(A1,1,1))+
((6-WEEKDAY(DATE(A1,1,1))<0)*7)+1)+((B1-1)*7)
```

Since some years have 52 weeks and some have 53—again depending on whether weeks end on Friday, Saturday, or Sunday—it is a good idea to modify the formulas so that they check to see if the date being returned is within the same year that you are analyzing. If you don't check this, then the formulas provided thus far will happily return dates for week 73, week 89, or week 123 of any given year—they simply adjust the date into the appropriate future year.

Here is the formula for weeks ending in Friday:

```=IF(YEAR(DATE(A1,1,6-WEEKDAY(DATE(A1,1,1))+
((6-WEEKDAY(DATE(A1,1,1))<0)*7)+1)+((B1-1)*7))=A1,
DATE(A1,1,6-WEEKDAY(DATE(A1,1,1))+((6-WEEKDAY(DATE(
A1,1,1))<0)*7)+1)+((B1-1)*7),"")
```

If the date calculated is not in the same year as what is specified in cell A1, then the formula returns nothing. Here is the formula for weeks ending in Saturday:

```=IF(YEAR(DATE(A1,1,1)+B1*7-WEEKDAY(DATE(A1,1,1)))=A1,
DATE(A1,1,1)+B1*7-WEEKDAY(DATE(A1,1,1)),"")
```

Finally, here is the formula for weeks ending in Sunday:

```=IF(YEAR(DATE(A1,1,1)+B1*7-WEEKDAY(DATE(A1,1,1))+1)=A1,
DATE(A1,1,1)+B1*7-WEEKDAY(DATE(A1,1,1))+1,"")
```

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (6750) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Calculating the Last Day in a Week Number.

Related Tips:

Save Time and Supercharge Excel! Automate virtually any routine task and save yourself hours, days, maybe even weeks. Then, learn how to make Excel do things you thought were simply impossible! Mastering advanced Excel macros has never been easier. Check out Excel 2010 VBA and Macros today!

 *Name: Email: Notify me about new comments ONLY FOR THIS TIP Notify me about new comments ANYWHERE ON THIS SITE Hide my email address *Text: *What is 5+3 (To prevent automated submissions and spam.)

Manoj Garg    03 Jan 2017, 06:24
Great
anwar    17 Aug 2015, 06:04
i used this formula of weeks end in sunday

=IF(YEAR(DATE(D2,1,1)+J2*7-WEEKDAY(DATE(D2,1,1))+1)=D2,DATE(D2,1,1)+J2*7-WEEKDAY(DATE(A1,1,1))+1,"")

it will give me a blank cell :(

# Our Company

Sharon Parq Associates, Inc.

# Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2016)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2016)

Excel Products

Word Products

# Our Authors

Author Index

Write for Tips.Net