Loading

Got a version of Excel that uses the
menu interface (Excel 97, Excel 2000, Excel 2002, or Excel 2003)?
**This site is for you!** If you
use a later version of Excel, visit
our *ExcelTips* site focusing on the ribbon interface.

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company.

Learn more about Allen...

ExcelTips FAQ

ExcelTips Resources

Ask an Excel Question

Make a Comment

Free Business Forms

Free Calendars

** Please Note:** This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later),

Anita has a worksheet with over 10,000 rows. Each row represent an individual contract. Each contract has a start date (column A) and an end date (column B). She needs a way to list in columns C, D, E, etc. the individual months covered by the contract. For instance, if column A contains 01 July 2009 and column B contains 30 September 2009, she needs column C to contain Jul 09, column D to contain Aug 09, and column E to contain Sep 09. Whatever formulas are used need to accommodate contract lengths that may be quite different.

There are several ways to go about such a task. It is possible to use some intermediate columns that specify things like the starting month and the number of months of each contract, but it turns out that such intermediate columns are not necessary. For instance, assuming that your contracts start in row 2, you could place the following formula in cell C2:

=TEXT(A2,"mmm yy")

Then, beginning in cell D2 you could place this formula:

=IF(DATE(YEAR($A2),MONTH($A2)+COLUMNS($D2:D2), DAY($A2))>$B2,"",TEXT(DATE(YEAR($A2),MONTH($A2) +COLUMNS($D2:D2),DAY($A2)),"mmm yy"))

This is one formula, and it uses the position of the cells containing the formula, along with the contract starting date, to calculate, basically, the month of offset from that starting month. The formula can be copied toward the right (columns E, F, G, etc.) for as far as necessary to display all the months and years.

The one drawback to the formula is that if the contract ending date is earlier in the month than the contract starting date, then the last month is not displayed. Thus, if the contract starts on 12 June 2012 and it ends on 05 February 2013, then the last month (February) will not be displayed by the formula. You could, instead, use the following formula in cell C2 and copy it to the right as far as necessary:

=IF(DATE(YEAR($A2),MONTH($A2)+COLUMN()-2,0) >DATE(YEAR($A2),MONTH($B2)+1,0),"",TEXT(DATE (YEAR($A2),MONTH($A2)+COLUMN()-2,0),"mmm yy"))

This formula also relies on the columns in which it resides, using them to calculate an offset from the contract start date. The formula will work just fine, regardless of the relationship between the contract start and end dates.

If you don't want to rely on column positioning, there is another approach you can take. Place the following formula in cell C2:

=(A2)

Then, in cell D2 place the following formula:

=IF($B2>C2,EOMONTH(C2,1),"")

Copy the formula in D2 to the right as many cells as necessary, and then format all those cells (including C2 and D2) as dates that display only the month and year. The formula will look at B2 (the contract ending date) to see if it is larger than C2. If it is, then the formula returns the serial number of the last day of the next month in series. If it is not, then a blank ("") is returned.

*ExcelTips* is your source for cost-effective Microsoft Excel training. This tip (5406) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Determining Month Names for a Range of Dates.

*Related Tips:*

**Solve Real Business Problems** Master business modeling and analysis techniques with Excel and transform data into bottom-line results. This hands-on, scenario-focused guide shows you how to use the latest Excel tools to integrate data from multiple tables. Check out *Microsoft Excel 2013 Data Analysis and Business Modeling* today!

The simplest solution is to drag the autofill handle so the months gets automatically filled