Figuring Out the Low-Score Winner

by Allen Wyatt (last updated January 9, 2015)

Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Figuring Out the Low-Score Winner.

Mike asked if there is a way to determine the low-score winner on a hole-by-hole basis in a golf game. He uses Excel to track the individual hole scores, but he needs to know who has the lowest unique score on each hole. (If there is a tie on a hole, then he doesn't need to know who was involved in the tie.)

In providing an answer, there are several assumptions that must be made. First, assume that the values 1-18 (for each golf hole) are in cells A2 through A19. Second, assume that the low-score winner will be noted in column B. Third, assume that there are four golfers playing, and that their names are in cells C1 through F1. This range (C1:F1) is named "GolferNames". Finally, the golf scores for each golfer are entered in cells C2 through F19.

With this structure used, there are any number of ways that the formula could be put together. I particularly like this formula, which should be placed in cell B2:

=IF(MIN(C2:F2)=SMALL(C2:F2,2),"There is a " &
TEXT(COUNTIF(C2:F2, MIN(C2:F2)),"0") & "-way tie",
INDEX(GolferNames,MATCH(MIN(C2:F2),C2:F2,0)))

This is a very long formula, and you should make sure that it is entered all on a single line. You can then copy the formula from B2 and paste it in B3 through B19.

If there is a tie (determined by comparing the results of the MIN function with the second lowest score, as returned by the SMALL function), then the formula returns "There is a 2-way tie", or whatever number is actually involved in a tie. If there is not a tie, then the INDEX function is used to retrieve the name of the golfer that had the lowest score for the hole.

This example used, of course, only four golfers. If there are more golfers involved, the only alterations to make involve changing the range covered by the GolferNames range and expanding all instances of C2:F2 in the formula to represent the actual range of golfer scores.

If you prefer to simply not list anything if there was a tie on a hole (i.e., don't say "There is a 2-way tie"), you can do so with this simplified version of the formula:

=IF(MIN(C2:F2)=SMALL(C2:F2,2),"",
INDEX(GolferNames,MATCH(MIN(C2:F2),
C2:F2,0)))

Comprehensive VBA Guide Visual Basic for Applications (VBA) is the language used for writing macros in all Office programs. This complete guide shows both professionals and novices how to master VBA in order to customize the entire Office suite for their needs. Check out Mastering VBA for Office 2010 today!