Loading
Excel.Tips.Net ExcelTips (Menu Interface)

Adjusting Test Scores Proportionately

Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Adjusting Test Scores Proportionately.

Mike is a teacher and often has to give tests to his students. In one instance he had 20 test scores that range from 76 down to 12. Mike wants to leave the top score at 76 but increase the bottom score by 5 (to 17) and then adjust all the in-between scores proportionately. He wonders if Excel has a function that will accomplish the adjustment for him.

There is no function that will do this, but there are any number of formulas that can be used to get the adjusted test scores. In fact, there are a surprisingly large number of formulas you can use. The reason why there are so many is because the word "proportionally" is ambiguous—what, exactly, does a proportional adjustment look like?

For instance, it could mean a portion of the difference between the lowest score and the highest score. Or, it could mean that the lower scores are "weighted" in some way so that they get a larger boost than the higher scores. Or, it could mean that you simply calculate what percentage the score is from the maximum score and then increase the score by that much.

With that in mind, let's look at a few ways you can adjust the scores. You'll want to look at the results of each formula and determine if they match your expectations for what should happen to the scores. These three formulas produce exactly the same adjustments to the scores, with the lower scores weighted more favorably than the higher scores:

=A1+(1-(A1-MIN(A:A))/(MAX(A:A)-MIN(A:A)))*5
=A1+(5*(MAX(A:A)-A1))/(MAX(A:A)-MIN(A:A))
=A1+(MAX(A:A)-A1)/(MAX(A:A)-MIN(A:A))*5

These formulas adjust the highest and lowest scores as required by Mike, and all other scores proportionally. It results, for example, in the mid-range score (half way between 12 and 76, which is a score of 42) being adjusted by 2.5 points.

The following simple formula only pays attention to the maximum value in the range of original scores. It calculates how far from the maximum the score is, and then adjusts the score upward. It results in a bottom adjusted score of 17.33, but that can be easily rounded to get to the desired amount.

=((MAX(A:A)-A1)/A1)+A1

The following formula examines the ranking of the original 19 scores, on a scale of 0 through 19. It then figures out what percentage of 5 that ranking represents and then adds the value to the original score:

=(RANK(A1,A:A)-1)*5/19+A1

You can also use linear regression to solve the problem. Excel has two built-in functions (SLOPE and INTERCEPT) that can be utilized to find the formula to determine the adjusted scores. In Mike's instance, the range of scores prior to adjustment is 12 to 76. These need to be adjusted to a range of 17 to 76. If you put 12 into cell E1, 76 into cell E2, 17 into cell F1, and 76 into cell F2, then you end up with the lows and highs in both the starting and ending ranges. You can then use these formulas to find the slope and intercept:

=SLOPE(F1:F2,E1:E2)
=INTERCEPT(F1:F2,E1:E2)

This calculates the slope at 0.921875 and the intercept at 5.9375. You can then apply these values to the original test scores in this manner:

=0.921875 * A1 + 5.9375

Interestingly enough, this linear regression approach returns the exact same values derived by the first three formulas presented at the beginning of this tip.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (1022) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Adjusting Test Scores Proportionately.

Related Tips:

Create Custom Apps with VBA! Discover how to extend the capabilities of Office 2013 (Word, Excel, PowerPoint, Outlook, and Access) with VBA programming, using it for writing macros, automating Office applications, and creating custom applications. Check out Mastering VBA for Office 2013 today!

 

Leave your own comment:

*Name:
Email:
  Notify me about new comments ONLY FOR THIS TIP
Notify me about new comments ANYWHERE ON THIS SITE
Hide my email address
*Text:
*What is 5+3 (To prevent automated submissions and spam.)
 
 
           Commenting Terms

Comments for this tip:

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)
 
 

Our Company

Sharon Parq Associates, Inc.

About Tips.Net

Contact Us

 

Advertise with Us

Our Privacy Policy

Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

DriveTips (Google Drive)

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2016)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2016)

Our Products

Helpful E-books

Newsletter Archives

 

Excel Products

Word Products

Our Authors

Author Index

Write for Tips.Net

Copyright © 2016 Sharon Parq Associates, Inc.