Please Note: This article is written for users of the following Microsoft Excel versions: 97, 2000, 2002, and 2003. If you are using a later version (Excel 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Excel, click here: Generating Random Testing Data.

Generating Random Testing Data

by Allen Wyatt
(last updated May 31, 2014)

When you develop worksheets that will be used by other people, you should test those worksheets to make sure that they work as you expect. This is particularly true of worksheets that contain complex formulas or will be used for critical purposes. The concept of testing a worksheet means that you will need to generate some sort of data to use in testing the worksheet.

Entire books have been written on putting together testing suites for software. How rigorous you are in compiling test data depends, in large part, on the needs of your audience and the nature of your worksheet. Unfortunately, there is no quick cure-all that will automatically figure out what you need and generate the data for you. There are tools in Excel, however, that you can use toward this end.

First, if you need to generate random numeric values, you can use the RAND or RANDBETWEEN worksheet functions. The difference is that RAND generates a value between 0 and 1, and RANDBETWEEN generates integer values between any bounds you set.

Random data may not be appropriate for your testing needs, however. This is particularly true when you are testing boundaries of your formulas. For instance, testing with large values, small values, or a combination of large and small values. Likewise, you may want to test for inappropriate values, such as using text as input rather than numbers (or vice versa). There are a whole contingent of conditions you need to think through, and then pick the type of data that is right for your needs.

If you prefer, you can use macros to generate testing data. The following macro fills a selected range of cells with a random numeric value, between whatever boundaries (minimum and maximum) that you set.

Sub RandNums()
    Dim MyRange As Range
    Dim lMin As Long, lMax As Long
    Dim dRand As Double

    ' If selection is not Excel Range
    If TypeName(Selection) <> "Range" Then Exit Sub

    Set MyRange = Selection

    ' Get Min and Max value
    lMin = CLng(InputBox("Minimum?"))
    lMax = CLng(InputBox("Maximum?"))

    Randomize
    Application.ScreenUpdating = False

    For Each c In MyRange.Cells
        ' Calculate random value, where
        ' Value >= Min And Value <= Max
        dRand = Rnd * (lMax - lMin) + lMin

        ' Use the following line only if the random
        ' value should be an integer
        ' dRand = Int(dRand)

        c.Value = dRand
    Next c

    Application.ScreenUpdating = True
End Sub

To use the macro, just select a range of cells that you want to contain random numeric values, and then run the macro. If you must use integer values in the cells, then you can "uncomment" the noted line within the macro.

If you want to fill a range of cells with random dates, then a slight modification to the RandNums macro results in the following.

Sub RandDates()
    Dim MyRange As Range
    Dim dtMin As Date, dtMax As Date
    Dim dtRand As Date

    ' If selection is not Excel Range
    If TypeName(Selection) <> "Range" Then Exit Sub

    Set MyRange = Selection

    ' Get Min and Max value
    ' From: 1/1/1990 (put your start Date)
    dtMin = #1/1/1990#
    ' To: Today
    dtMax = Date

    Randomize
    Application.ScreenUpdating = False

    For Each c In MyRange.Cells
        ' Calculate random value, where
        ' Value >= Min And Value <= Max
        dtRand = Rnd * (dtMax - dtMin) + dtMin
        dtRand = Int(dtRand)

        c.Value = dtRand
        ' Change format for cell, below, as desired
        c.NumberFormat = "m/d/yyyy"
    Next c

    Application.ScreenUpdating = True
End Sub

Again, just select a range and then run the macro. You can modify the initial values set to the dtMin and dtMax variables in order to specify the boundaries for the dates desired. You can also, if desired, change the formatting applied to the cells after the random date is stored within the cells.

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (2077) applies to Microsoft Excel 97, 2000, 2002, and 2003. You can find a version of this tip for the ribbon interface of Excel (Excel 2007 and later) here: Generating Random Testing Data.

Author Bio

Allen Wyatt

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He  is president of Sharon Parq Associates, a computer and publishing services company. ...

MORE FROM ALLEN

Disabling Shift Key Use when Opening a Workbook

Open up a workbook, and Excel normally runs the macros associated with that workbook. You can disable the automatic running ...

Discover More

Adding Fonts to Docs

If Docs only provided one or two fonts for displaying document text, it wouldn't be taken seriously as a word processor. ...

Discover More

Conditional Printing

If you need to make what Excel prints be based upon conditions in a worksheet, you'll love the information in this tip. There ...

Discover More

Save Time and Supercharge Excel! Automate virtually any routine task and save yourself hours, days, maybe even weeks. Then, learn how to make Excel do things you thought were simply impossible! Mastering advanced Excel macros has never been easier. Check out Excel 2010 VBA and Macros today!

MORE EXCELTIPS (MENU)

Appearance of Excel on the Taskbar

Do you want Excel to use a task button, on the Windows Taskbar, for each of your open worksheets? Then just make this simple ...

Discover More

Viewing Your Work Full-Screen

Want to use the maximum space possible for displaying information on screen? You'll want to learn how to use the full-screen ...

Discover More

Thoughts and Ideas on Significant Digits in Excel

Ruminations and reflections about significant digits in Excel. Includes examples of how significant digits can affect the ...

Discover More
Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

View most recent newsletter.

Comments for this tip:

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)

This Site

Got a version of Excel that uses the menu interface (Excel 97, Excel 2000, Excel 2002, or Excel 2003)? This site is for you! If you use a later version of Excel, visit our ExcelTips site focusing on the ribbon interface.

Subscribe

FREE SERVICE: Get tips like this every week in ExcelTips, a free productivity newsletter. Enter your address and click "Subscribe."

(Your e-mail address is not shared with anyone, ever.)

View the most recent newsletter.

Links and Sharing
Share