Loading
Excel.Tips.Net ExcelTips (Menu Interface)

Deleting Macros from within a Macro

Gene asked for a way to delete macros from within a macro. He has a large worksheet that uses macros to put together a purchase order. As the last step, the macro deletes the original data that is no longer necessary for the finished purchase order. This pared-down workbook is then saved under a new name. Gene needs the macro, just prior to saving, to delete a macro that is stored in SelectionChange event handler.

There are a couple of ways that this could be handled. One way is to avoid having to do the deletion all together. Instead, have your macro create a new workbook and then transfer, to that workbook, a copy of the data you need. You could then slice and dice the data in the new workbook and save it as your purchase order. The macros in the existing workbook are never copied to the new workbook during the process, so you don't need to worry about deleting them.

Copying all the worksheets in the current workbook to a new workbook is very easy to do. The following macro shows how it is done:

Sub CopyThisWorkbook()
    Dim CopiedWB As String

    CopiedWB = "Copy of " & ActiveWorkbook.Name

    Sheets.Copy
    ActiveWorkbook.SaveAs Filename:=CopiedWB, _
      FileFormat:=xlNormal
End Sub

The Copy method, when applied to the Sheets collection, copies all the worksheets in the active workbook to a new workbook and makes the new workbook active. The final command saves the new workbook under a new name.

Of course, if you need some of your macros to be in the new workbook, but not all of them (such as the SelectionChange event handler), then you are probably best to delete what you don't need and simply save under a new name. The following example macro shows how to delete the SelectionChange event handler from the worksheet code for Sheet1.

Sub DeleteProcedure()
    Dim VBCodeMod As CodeModule
    Dim StartLine As Long
    Dim HowManyLines As Long

    Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("Sheet1").CodeModule
    With VBCodeMod
        StartLine = .ProcStartLine("Worksheet_SelectionChange", _
          vbext_pk_Proc)
        HowManyLines = .ProcCountLines("Worksheet_SelectionChange", _
          vbext_pk_Proc)
        .DeleteLines StartLine, HowManyLines
    End With
End Sub

After the macro is completed, the workbook could be saved, and the desired macro won't be in the saved file. This macro is adapted from information provided at Chip Pearson's Web site, which you should reference if you need additional information on this technique:

http://www.cpearson.com/excel/vbe.aspx

ExcelTips is your source for cost-effective Microsoft Excel training. This tip (3073) applies to Microsoft Excel 97, 2000, 2002, and 2003.

Related Tips:

Solve Real Business Problems Master business modeling and analysis techniques with Excel and transform data into bottom-line results. This hands-on, scenario-focused guide shows you how to use the latest Excel tools to integrate data from multiple tables. Check out Microsoft Excel 2013 Data Analysis and Business Modeling today!

 

Leave your own comment:

*Name:
Email:
  Notify me about new comments ONLY FOR THIS TIP
Notify me about new comments ANYWHERE ON THIS SITE
Hide my email address
*Text:
*What is 5+3 (To prevent automated submissions and spam.)
 
 
           Commenting Terms

Comments for this tip:

There are currently no comments for this tip. (Be the first to leave your comment—just use the simple form above!)
 
 

Our Company

Sharon Parq Associates, Inc.

About Tips.Net

Contact Us

 

Advertise with Us

Our Privacy Policy

Our Sites

Tips.Net

Beauty and Style

Cars

Cleaning

Cooking

DriveTips (Google Drive)

ExcelTips (Excel 97–2003)

ExcelTips (Excel 2007–2016)

Gardening

Health

Home Improvement

Money and Finances

Organizing

Pests and Bugs

Pets and Animals

WindowsTips (Microsoft Windows)

WordTips (Word 97–2003)

WordTips (Word 2007–2016)

Our Products

Helpful E-books

Newsletter Archives

 

Excel Products

Word Products

Our Authors

Author Index

Write for Tips.Net

Copyright © 2016 Sharon Parq Associates, Inc.