Finding the Lowest Numbers

You may have a need at some point to find the lowest numbers in a list of values. This is relatively easy to do if you use the SMALL worksheet function. The function takes two parameters: the range of the values to be evaluated and an indicator of which smallest number you want. For instance, the following will return the second lowest number in the range of A1:A100:

=SMALL(A1:A100,2)

If you wanted to know the two lowest numbers in the range, then use two formulas containing the SMALL function—one with 1 as the second parameter (for the lowest number) and one with 2 as the second parameter (for the second lowest number).

There are situations, of course, where the two smallest numbers in the range could actually be the same number. For instance, if the lowest number is 3 and there is a second 3 in the list, then both the lowest numbers will be the same. If you want the two lowest unique numbers then you will need to use a macro to determine them.

Function SMALLn(rng As Range, n)
    Application.Volatile
    SMALLn = False
    If n < 1 Then Exit Function
    Dim i As Long, j As Long, k As Long, min, arr, arr2
    arr = Application.Transpose(rng)
    ReDim arr2(n - 1)
    min = Application.WorksheetFunction.Min(arr)
    j = UBound(arr)
    k = 0
    arr2(k) = min
    For i = 1 To j
        If Application.Small(arr, i) <> arr2(k) Then
            k = k + 1
            arr2(k) = Application.Small(arr, i)
            If k = n - 1 Then
                SMALLn = arr2(k)
                Exit For
            End If
        End If
    Next i
End Function

This user-defined function is used in the following manner:

=SMALLn(A1:A100,2)

When called like this, the function returns the second lowest unique value in the specified range.