Visually Showing a Protection Status

Todd has developed a workbook used by others. To prevent data from being ruined, he's protected the worksheet as well as the workbook. The problem is, Todd sometimes forgets to protect the worksheet and workbook after making changes. He is wondering if there is a way to create a visual indicator that shows whether the worksheet/workbook is currently protected or unprotected.

Of course, the easiest way to check to see if something is unprotected is to just start looking at the menu choices available. If the full range of choices is there, then the worksheet and workbook are unprotected. If there are significant parts that are unavailable ("grayed out"), then protection is turned on.

Another easy solution is to create a user-defined function that returns a value indicating whether the workbook or worksheet are protected. The following will do the trick:

Function WksProtected(rng As Range) As String
    Application.Volatile
    If rng.Parent.ProtectContents Then
        WksProtected = "Protected"
    Else
        WksProtected = "Not Protected"
    End If
End Function

Function WkbProtected(rng As Range) As String
    Application.Volatile
    If rng.Parent.Parent.ProtectStructure Then
        WkbProtected = "Protected"
    Else
        WkbProtected = "Not Protected"
    End If
End Function

To use the macros, just include formulas like the following anywhere in the worksheet:

=WksProtected(A1)
=WkbProtected(A1)

The result of the formulas is either "Protected" or "Not Protected," depending on the state of the worksheets and workbook. You could use conditional formatting to highlight the cells based on what is returned by the functions.