Retrieving Drive Statistics

If you are creating a full-blown application using Excel, you may want to know a bit about the environment in which your application is running. For instance, you might want to know how many drives are attached to the system, what their drive letters are, and how much space they have free.

The following macro will retrieve the requested information. All you need to do is provide the column headings. The macro assumes that you'll have three columns: In cell A1 you should place the heading "Drive," in cell B1 you place the heading "Free%," and in cell C1 you place the heading "Used%." In addition, you should format columns B and C as percentages.

Sub DriveSizes()
    Dim Drv As Drive
    Dim fs As New FileSystemObject
    Dim Letter As String
    Dim Total As Variant
    Dim Free As Variant
    Dim FreePercent As Variant
    Dim TotalPercent As Variant
    Dim i As Integer

    On Error Resume Next
    i = 2
    For Each Drv In fs.drives
        If Drv.IsReady Then
            Letter = Drv.DriveLetter
            Total = Drv.TotalSize
            Free = Drv.FreeSpace

            FreePercent = Free / Total
            TotalPercent = 1 - FreePercent

            Cells(i, 1).Value = Letter
            Cells(i, 2).Value = FreePercent
            Cells(i, 3).Value = TotalPercent
            i = i + 1
        End If
    Next
End Sub

When you first run this macro, you may get an error. If you do, it means that you need to configure your macro to reference the Microsoft Scripting Runtime. Follow these steps from within the VBA Editor:

1. Choose the References option from the Tools menu. VBA displays the References dialog box.
2. In the list of available references, make sure Microsoft Scripting Runtime is selected.
3. Click on OK.

Now the macro should run just fine, and you will have a fully populated table representing all the drives available on your system. (If your system has drives that use removeable media—such as floppy drives—they may not show up unless you have media in them.)