Changing AutoFilter Drop-Down Arrow Colors

Gus asked if there was a way to change the color of the drop-down arrows that appear at the top of each column when AutoFilter is turned on. When a filter is not applied to a column, the drop-down arrow is black; when a filter is applied, the drop-down arrow is navy blue. Gus wanted to change the colors because there isn't enough contrast between black and navy blue on his monitor.

Unfortunately, it appears that the color of the drop-down arrows is hard-coded into Excel and cannot be changed. You can try a workaround, if you desire, that would instead color the first cell in each of the filtered columns. Add the following macro to a regular module in the workbook:

Sub ColorDisplayFilter()
    Dim flt As Filter
    Dim iCol As Integer
    Dim lRow As Long

    iCol = 0
    lRow = ActiveSheet.AutoFilter.Range.Row
    Application.EnableEvents = False
    For Each flt In ActiveSheet.AutoFilter.Filters
        iCol = iCol + 1
        If flt.On Then
            Cells(lRow, iCol).Interior.Color = vbYellow
        Else
            Cells(lRow, iCol).Interior.ColorIndex = xlColorIndexNone
        End If
    Next flt
    Application.EnableEvents = True
End Sub

The code steps through the filters for a worksheet and, if the filter is active for a column, colors the first cell yellow. If the filter is not active, then it gets rid of the yellow color.

To trigger the routine so that it runs automatically, there are two things you need to do. First of all, you need to add the following macro to the thisWorkbook object:

Private Sub Workbook_SheetCalculate(ByVal Sh As Object)
    If Sh.AutoFilterMode Then ColorDisplayFilter
End Sub

This triggers every time the worksheet is calculated. If the AutoFilterMode property is True, then the coloring macro is executed.

The second thing you need to do is add a SUBTOTAL formula to your worksheet. Assuming that column A is one of the columns in the filter, you could add the following to the worksheet:

=SUBTOTAL(9,A:A)

The SUBTOTAL function is recalculated every time a filter is changed, so this helps ensure that the coloring macro is executed. The formula can be hidden, if desired, but it must be on the worksheet that has the filter to ensure that the sheet triggers the event.