Printing Selected Worksheets

If you have a lot of workbooks that have accumulated over the years, you may have a need to print some of the worksheets out of each of them. For instance, you might have a folder that contains a workbook for each of your company's divisions for the previous decade. If your company has eight divisions, that means you have 80 workbooks in the folder. Now, if you need to print the second-quarter and third-quarter figures (from the second and third worksheets out of each workbook), you start to see the problem. Loading each workbook and then printing selected sheets could take a huge amount of time.

A quicker way is to create a macro that will do the printing for you. The following macro starts by asking you for a directory path. Provided that you specify a path, the macro then starts to load each XLS (Excel) file in the directory, and then print the second and third worksheet from each one. Once printed, the worksheet is closed.

Public Sub PrintWorkbooks()
    Dim sCurFile As String
    Dim sPath As String

    'Get the path
    sPath = InputBox("Starting path?", "PrintWorkbooks")
    If sPath <> "" Then
        On Error Resume Next
        Application.ScreenUpdating = False
        If Right(sPath, 1) <> "\" Then
            sPath = sPath & "\"
        End If
        sCurFile = Dir(sPath & "*.xls", vbNormal)
        Do While Len(sCurFile) <> 0
            Workbooks.Open sPath & sCurFile, , True
            With Workbooks(sCurFile)
                .Worksheets(2).PrintOut
                .Worksheets(3).PrintOut
                .Close SaveChanges:=False
            End With
            sCurFile = Dir
            DoEvents
        Loop
        Application.ScreenUpdating = True
        On Error GoTo 0
    End If
End Sub

You should note that this macro specifically searches for files that have the XLS extension. If you are using Excel 2007, your workbook files may use the XLSM or XLSX extensions. If you know what they are using, just change the XLS designation in the code to the appropriate extension. If your worksheets could have any of the three extensions (XLS, XLSM, or XLSX), then change the "xls" designation in the code to "xls*". The asterisk will match anything that may follow XLS, which should address all the variants.

Obviously, if you have quite a few workbooks in the directory, printing could take quite some time. You may want to find some time when you have nothing else to do, and then just let the macro start running.