Selective Headers and Footers

One of the long-time complaints about Excel is that it doesn't have a very robust method of creating and managing headers and footers. Consider the following scenario: You want to print your worksheet, but only have page numbers beginning on the second page.

There is no intrinsic method in Excel to handle this situation. There are some workarounds; for instance, you could put your first page on one worksheet (without headers or footers) and the subsequent pages on a different worksheet (which includes headers and footers). You could then print the two worksheets in one pass, and effectively achieve your goal. You could also use the Report Manager to put together different reports based on the information in your worksheet. (Using the Report Manager has been covered in other issues of ExcelTips.)

Neither of these approaches will work for all situations, however. For instance, you may not be able to split your printout into multiple worksheets, or you may not have much experience with the Report Manager. If you prefer, you can create a macro which will print your worksheet as you desire.

The following macro, GoodPrint, will print the first page of a worksheet without headers or footers, and then all subsequent pages as normal.

Sub GoodPrint()
    Dim hlft As String
    Dim hctr As String
    Dim hrgt As String
    Dim flft As String
    Dim fctr As String
    Dim frgt As String

    'save current header
    hlft = ActiveSheet.PageSetup.LeftHeader
    hctr = ActiveSheet.PageSetup.CenterHeader
    hrgt = ActiveSheet.PageSetup.RightHeader

    'save current footer
    flft = ActiveSheet.PageSetup.LeftFooter
    fctr = ActiveSheet.PageSetup.CenterFooter
    frgt = ActiveSheet.PageSetup.RightFooter

    'remove header
    With ActiveSheet.PageSetup
        .CenterHeader = ""
        .RightHeader = ""
        .LeftHeader = ""
        .CenterFooter = ""
        .RightFooter = ""
        .LeftFooter = ""
    End With

    'print page one
    ActiveSheet.PrintOut 1, 1

    'restore header
    With ActiveSheet.PageSetup
        .LeftHeader = hlft
        .CenterHeader = hctr
        .RightHeader = hrgt
        .LeftFooter = flft
        .CenterFooter = fctr
        .RightFooter = frgt
    End With

    'print the rest of the pages
    ActiveSheet.PrintOut 2
End Sub