Using a Different Footer on Secondary Pages

When creating a worksheet that will eventually be printed, you may want to use a different footer on the first page of your document than you do on the subsequent pages. There is no way to do this directly in Excel. There are a couple of workarounds you could use, however.

First of all, try using the Report Manager add-in for Excel. This add-in allows you to define different views and select the order in which those views are printed. Each view can also have its unique headers and footers, which means you could set up a view of the first page—with the footer desired—and a view of the subsequent pages with their own headers and footers. You would then print the report using the Report Manager, resulting in the desired output.

You should note that the Report Manager add-in was last distributed with Excel 2002. If you are using Excel 2003 or Excel 2007, you can still use the Report Manager. This Knowledge Base article explains how you can use it:

http://support.microsoft.com/?kbid=873209

Another workaround is to use a macro to do your printing. The following macro will set the footers for a worksheet depending on what is being printed. Actually, it sets the footers for the first page, and then prints that page. Then it sets the footers for the other pages, and prints them.

Sub PrintSheet()
    Dim sP1Left As String
    Dim sP1Center As String
    Dim sP1Right As String
    Dim sP2Left As String
    Dim sP2Center As String
    Dim sP2Right As String

    ' Define first-page footers
    sP1Left = "First page left"
    sP1Center = "First page center"
    sP1Right = "First page right"

    ' Define second-page footers
    sP2Left = "Second page left"
    sP2Center = "Second page center"
    sP2Right = "Second page right"

    ' Set up and print first page
    With ActiveSheet.PageSetup
        .LeftFooter = sP1Left
        .CenterFooter = sP1Center
        .RightFooter = sP1Right
    End With
    ActiveSheet.PrintOut 1, 1

    ' Set up and print other pages
    With ActiveSheet.PageSetup
        .LeftFooter = sP2Left
        .CenterFooter = sP2Center
        .RightFooter = sP2Right
    End With
    ActiveSheet.PrintOut 2
End Sub

To use the macro, all you need to do is change the footer definitions. Change the variable values in the "Define first-page footers" area and the "Define second-page footers" area in order to get just the output you want.