Using an Exact Number of Digits

Henk asked if there is a way in Excel to display a number using six digits, independent of the placement of the decimal point. For instance, 0.1 would be displayed as 0.10000, 200 would be displayed as 200.000, and 25000 would be displayed as 25000.0.

Unfortunately, there is no formatting that will do the trick; all display formatting seems to be dependent on the position of the decimal point. You can format a display for a specific number of digits after the decimal point, but that number of digits will be used regardless of how many digits appear before the decimal point.

Several ExcelTips subscribers came up with suggestions that involve using formulas to display the number as desired. For instance, the following formula will display the value in A1 using six digits:

=FIXED(A1,IF(ABS(A1)<1,5,5-INT(LOG(ABS(A1)))),TRUE)

Other readers provided formulas that relied on converting the number to a text string and displaying it as such. Converting a number to its textual equivalent, however, has the distinct drawback of no longer being able to use the number in other formulas. (Remember—it is text at this point, not a number.) The above formula does not have that limitation.

If you wanted to, you could also use a macro to set the formatting within a cell that contains a value. The advantage to such a macro is that you don't have to use a cell for a formula, as shown above. The drawback to a macro is that you need to remember to run it on the cells whenever values within them change. The following macro is an example of such an approach:

Sub SetFigures()
    Dim iDecimals As Integer
    Dim bCommas As Boolean
    Dim sFormat As String
    Dim CellRange As Range
    Dim TestCell As Range

    bCommas = False 'Change as desired

    Set CellRange = Selection
    For Each TestCell In CellRange
        If Abs(TestCell.Value) < 1 Then
            iDecimals = 5
        Else
            iDecimals = 5 - Int(Log(Abs(TestCell.Value)) / Log(10#))
        End If

        sFormat = "0"
        If bCommas Then sFormat = "#,##0"
        If iDecimals < 0 Then sFormat = "General"
        If iDecimals > 0 Then sFormat = sFormat & _
          "." & String(iDecimals, "0")

        TestCell.NumberFormat = sFormat
    Next TestCell
End Sub

In order to use the macro, simply select the cells you want to format, then execute it. Each cell in the range you selected is set to display six digits, unless the number in the cell is too large or too small.